Rules for integrands of the form (((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)

0:  ∫(x^m) (((d+(e/x)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==q ∧ q∈ℤ

Derivation: Algebraic simplification

Rule: If  m==q ∧ q∈ℤ, then

∫(x^m) (((d+(e/x)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((e+d x))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[x_^m_.*(d_+e_./x_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Int[(e+d*x)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && EqQ[m,q] && IntegerQ[q]

1:  ∫(x^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  q∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Rule: If  q∈(SuperPlus[ℤ])∧ m∈ℤ, let u->∫(x^m) (((d+e (x^r)))^q)dx, then

∫(x^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*x^r)^q,x]},
  u*(a+b*Log[c*x^n]) - b*n*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[q,0] && IGtQ[m,0]

Int[x_^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*x^r)^q,x]},
  Dist[(a+b*Log[c*x^n]),u] - b*n*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[q,0] && IntegerQ[m] && Not[EqQ[q,1] && EqQ[m,-1]]

2:  ∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  m+r(q+1)+1==0 ∧ m≠-1

Derivation: Integration by parts

Basis: If  m+r(q+1)+1==0 ∧ m≠-1, then (((f x))^m) (((d+e (x^r)))^q)==(∂_x)(((((f x))^(m+1)) (((d+e (x^r)))^(q+1)))/(d f (m+1)))

Rule: If  m+r(q+1)+1==0 ∧ m≠-1, then

∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  (((((f x))^(m+1)) (((d+e (x^r)))^(q+1)) (a+b Log[c (x^n)]))/(d f (m+1)))-((b n)/(d (m+1)))∫(((f x))^m) (((d+e (x^r)))^(q+1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])/(d*f*(m+1)) - 
  b*n/(d*(m+1))*Int[(f*x)^m*(d+e*x^r)^(q+1),x] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && EqQ[m+r*(q+1)+1,0] && NeQ[m,-1]

3.  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])

1.  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0)

1:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r==n

Derivation: Integration by substitution

Rule: If  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r==n, then

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ((f^m)/n) Subst[∫(((d+e x))^q) (((a+b Log[c x]))^p)dx,x,(x^n)]

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*x_^n_])^p_.,x_Symbol] :=
  f^m/n*Subst[Int[(d+e*x)^q*(a+b*Log[c*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && EqQ[m,r-1] && IGtQ[p,0] && (IntegerQ[m] || GtQ[f,0]) && EqQ[r,n]

2.  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n

1:  ∫(((((f x))^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n

Derivation: Integration by parts

Basis: ((((f x))^m)/(d+e (x^r)))==((f^m)/(e r))(∂_x)Log[1+((e (x^r))/d)]

Rule: If  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n, then

∫(((((f x))^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  ⟶  (((f^m) Log[1+((e (x^r))/d)] (((a+b Log[c (x^n)]))^p))/(e r))-((b (f^m) n p)/(e r)) ∫((Log[1+((e (x^r))/d)] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*Log[c_.*x_^n_.])^p_./(d_+e_.*x_^r_),x_Symbol] :=
  f^m*Log[1+e*x^r/d]*(a+b*Log[c*x^n])^p/(e*r) - 
  b*f^m*n*p/(e*r)*Int[Log[1+e*x^r/d]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,f,m,n,r},x] && EqQ[m,r-1] && IGtQ[p,0] && (IntegerQ[m] || GtQ[f,0]) && NeQ[r,n]

2:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n ∧ q≠-1

Derivation: Integration by parts

Rule: If  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n ∧ q≠-1, then

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  (((f^m) (((d+e (x^r)))^(q+1)) (((a+b Log[c (x^n)]))^p))/(e r (q+1)))-((b (f^m) n p)/(e r (q+1))) ∫(((((d+e (x^r)))^(q+1)) (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  f^m*(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])^p/(e*r*(q+1)) - 
  b*f^m*n*p/(e*r*(q+1))*Int[(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && EqQ[m,r-1] && IGtQ[p,0] && (IntegerQ[m] || GtQ[f,0]) && NeQ[r,n] && NeQ[q,-1]

2:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ ¬(m∈ℤ ∨ f>0)

Derivation: Piecewise constant extraction

Rule: If  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ ¬(m∈ℤ ∨ f>0), then

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ((((f x))^m)/(x^m)) ∫(x^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(f_*x_)^m_.*(d_+e_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  (f*x)^m/x^m*Int[x^m*(d+e*x^r)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && EqQ[m,r-1] && IGtQ[p,0] && Not[(IntegerQ[m] || GtQ[f,0])]

?.  ∫(((x^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  when  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ])∧ m∈ℤ

x:  ∫(((x^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  when  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ])∧ m-r+1∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ((x^m)/(d+e (x^r)))==((x^(m-r))/e)-((d (x^(m-r)))/(e (d+e (x^r))))

Rule: If  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ])∧ m-r+1∈(SuperPlus[ℤ]), then

∫(((x^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  ⟶  (1/e) ∫(x^(m-r)) (((a+b Log[c (x^n)]))^p)dx-(d/e) ∫(((x^(m-r)) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx

Program code:

(* Int[x_^m_.*(a_.+b_.*Log[c_.*x_^n_.])^p_./(d_+e_.*x_^r_.),x_Symbol] :=
  1/e*Int[x^(m-r)*(a+b*Log[c*x^n])^p,x] - 
  d/e*Int[(x^(m-r)*(a+b*Log[c*x^n])^p)/(d+e*x^r),x] /;
FreeQ[{a,b,c,d,e,m,n,r},x] && IGtQ[p,0] && IGtQ[r,0] && IGeQ[m-r,0] *)

2.  ∫(((x^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  when  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ])∧ m∈(SuperMinus[ℤ])

1.  ∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  when  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ])

1:  ∫((a+b Log[c (x^n)])/(x (d+e (x^r))))dx  when  (r/n)∈ℤ

Derivation: Integration by substitution

Basis: ((F[(x^n)])/x)==(1/n) Subst[((F[x])/x),x,(x^n)] (∂_x)(x^n)

Rule: If (r/n)∈ℤ, then

∫((a+b Log[c (x^n)])/(x (d+e (x^r))))dx  ⟶  (1/n) Subst[∫((a+b Log[c x])/(x (d+e (x^(r/n)))))dx,x,(x^n)]

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_])/(x_*(d_+e_.*x_^r_.)),x_Symbol] :=
  1/n*Subst[Int[(a+b*Log[c*x])/(x*(d+e*x^(r/n))),x],x,x^n] /;
FreeQ[{a,b,c,d,e,n,r},x] && IntegerQ[r/n]

x:  ∫((((a+b Log[c (x^n)]))^p)/(x (d+e x)))dx  when  p∈(SuperPlus[ℤ])

Rule: Algebraic expansion

Basis: (1/(x (d+e x)))==(1/(d x))-(e/(d (d+e x)))

Note: This rule returns antiderivative in terms of ((e x)/d) instead of (d/(e x)), but requires more steps and one more term.

Rule: If  p∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (x^n)]))^p)/(x (d+e x)))dx  ⟶  (1/d)∫((((a+b Log[c (x^n)]))^p)/x)dx-(e/d)∫((((a+b Log[c (x^n)]))^p)/(d+e x))dx

Program code:

(* Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(x_*(d_+e_.*x_)),x_Symbol] :=
  1/d*Int[(a+b*Log[c*x^n])^p/x,x] - e/d*Int[(a+b*Log[c*x^n])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,0] *)

x:  ∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  when  p∈(SuperPlus[ℤ])

Rule: Integration by parts

Basis: (1/(x (d+e (x^r))))==(∂_x)((r Log[x]-Log[1+((e (x^r))/d)])/(d r))

Basis: (∂_x)(((a+b Log[c (x^n)]))^p)==((b n p (((a+b Log[c (x^n)]))^(p-1)))/x)

Note: This rule returns antiderivatives in terms of  (x^r) instead of  (x^(-r)), but requires more steps and larger antiderivatives.

Rule: If  p∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  ⟶  
(((r Log[x]-Log[1+((e (x^r))/d)]) (((a+b Log[c (x^n)]))^p))/(d r))-((b n p)/d)∫((Log[x] (((a+b Log[c (x^n)]))^(p-1)))/x)dx+((b n p)/(d r))∫((Log[1+((e (x^r))/d)] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

(* Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(x_*(d_+e_.*x_^r_.)),x_Symbol] :=
  (r*Log[x]-Log[1+(e*x^r)/d])*(a+b*Log[c*x^n])^p/(d*r) - 
  b*n*p/d*Int[Log[x]*(a+b*Log[c*x^n])^(p-1)/x,x] + 
  b*n*p/(d*r)*Int[Log[1+(e*x^r)/d]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[p,0] *)

2:  ∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  when  p∈(SuperPlus[ℤ])

Rule: Integration by parts

Basis: (1/(x (d+e (x^r))))==-(1/(d r)) (∂_x)Log[1+(d/(e (x^r)))]

Rule: If  p∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  ⟶  -((Log[1+(d/(e (x^r)))] (((a+b Log[c (x^n)]))^p))/(d r))+((b n p)/(d r))∫((Log[1+(d/(e (x^r)))] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(x_*(d_+e_.*x_^r_.)),x_Symbol] :=
  -Log[1+d/(e*x^r)]*(a+b*Log[c*x^n])^p/(d*r) + 
  b*n*p/(d*r)*Int[Log[1+d/(e*x^r)]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[p,0]

2:  ∫(((x^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  when  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ])∧ m+1∈(SuperMinus[ℤ])

Derivation: Algebraic expansion

Basis: ((x^m)/(d+e (x^r)))==((x^m)/d)-((e (x^(m+r)))/(d (d+e (x^r))))

Rule: If  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ])∧ m+1∈(SuperMinus[ℤ]), then

∫(((x^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  ⟶  (1/d) ∫(x^m) (((a+b Log[c (x^n)]))^p)dx-(e/d) ∫(((x^(m+r)) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx

Program code:

Int[x_^m_.*(a_.+b_.*Log[c_.*x_^n_.])^p_./(d_+e_.*x_^r_.),x_Symbol] :=
  1/d*Int[x^m*(a+b*Log[c*x^n])^p,x] - 
  e/d*Int[(x^(m+r)*(a+b*Log[c*x^n])^p)/(d+e*x^r),x] /;
FreeQ[{a,b,c,d,e,m,n,r},x] && IGtQ[p,0] && IGtQ[r,0] && ILtQ[m,-1]

?.  ∫(((f x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  when  m+q+1∈(SuperMinus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q<-1

1:  ∫(((f x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  when  m+q+2==0 ∧ p∈(SuperPlus[ℤ])∧ q<-1

Derivation: Integration by parts

Basis: If  m+q+2==0, then (((f x))^m) (((d+e x))^q)==-(∂_x)(((((f x))^(m+1)) (((d+e x))^(q+1)))/(d f (q+1)))

Basis: (∂_x)(((a+b Log[c (x^n)]))^p)==((b n p (((a+b Log[c (x^n)]))^(p-1)))/x)

Rule: If  m+q+2==0 ∧ p∈(SuperPlus[ℤ])∧ q<-1, then

∫(((f x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  
-(((((f x))^(m+1))(((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^p))/(d f (q+1)))+((b n p)/(d (q+1))) ∫(((f x))^m) (((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^(p-1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_)^q_*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  -(f*x)^(m+1)*(d+e*x)^(q+1)*(a+b*Log[c*x^n])^p/(d*f*(q+1)) + 
  b*n*p/(d*(q+1))*Int[(f*x)^m*(d+e*x)^(q+1)*(a+b*Log[c*x^n])^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,m,n,q},x] && EqQ[m+q+2,0] && IGtQ[p,0] && LtQ[q,-1]

2.  ∫(((f x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  when  m+q+2∈(SuperMinus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q<-1 ∧ m>0

1:  ∫(x^m) (((d+e x))^q) (a+b Log[c (x^n)])dx  when  m+q+2∈(SuperMinus[ℤ])∧ m∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Rule: If  m+q+2∈(SuperMinus[ℤ])∧ m∈(SuperPlus[ℤ]), let u->∫(x^m) (((d+e x))^q)dx, then

∫(x^m) (((d+e x))^q) (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[x_^m_.*(d_+e_.*x_)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*x)^q,x]},
  Dist[(a+b*Log[c*x^n]),u,x] - b*n*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{a,b,c,d,e,n},x] && ILtQ[m+q+2,0] && IGtQ[m,0]

2:  ∫(((f x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  when  m+q+2∈(SuperMinus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q<-1 ∧ m>0

Derivation: Algebraic expansion and integration by parts

Basis: (((d+e x))^q)==-(((((d+e x))^q) (d (m+1)+e (m+q+2) x))/(d (q+1)))+(((m+q+2) (((d+e x))^(q+1)))/(d (q+1)))

Basis: (((f x))^m) (((d+e x))^q) (d (m+1)+e (m+q+2) x)==(∂_x)(((((f x))^(m+1)) (((d+e x))^(q+1)))/f)

Basis: (∂_x)(((a+b Log[c (x^n)]))^p)==((b n p (((a+b Log[c (x^n)]))^(p-1)))/x)

Rule: If  m+q+2∈(SuperMinus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q<-1 ∧ m>0, then

∫(((f x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx

  ⟶  -(1/(d (q+1))) ∫(((f x))^m) (((d+e x))^q) (d (m+1)+e (m+q+2) x) (((a+b Log[c (x^n)]))^p)dx+((m+q+2)/(d (q+1)))∫(((f x))^m) (((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^p)dx

  ⟶  -(((((f x))^(m+1)) (((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^p))/(d f (q+1)))+((b n p)/(d (q+1)))∫(((f x))^m) (((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^(p-1))dx+
((m+q+2)/(d (q+1)))∫(((f x))^m) (((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_)^q_*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  -(f*x)^(m+1)*(d+e*x)^(q+1)*(a+b*Log[c*x^n])^p/(d*f*(q+1)) + 
  (m+q+2)/(d*(q+1))*Int[(f*x)^m*(d+e*x)^(q+1)*(a+b*Log[c*x^n])^p,x] + 
  b*n*p/(d*(q+1))*Int[(f*x)^m*(d+e*x)^(q+1)*(a+b*Log[c*x^n])^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,n},x] && ILtQ[m+q+2,0] && IGtQ[p,0] && LtQ[q,-1] && GtQ[m,0]

4.  ∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  q+1∈(SuperMinus[ℤ])

1:  ∫(((f x))^m) (((d+e x))^q) (a+b Log[c (x^n)])dx  when  q+1∈(SuperMinus[ℤ])∧ m>0

Rule: If  q+1∈(SuperMinus[ℤ])∧ m>0, then

∫(((f x))^m) (((d+e x))^q) (a+b Log[c (x^n)])dx  ⟶  
(((((f x))^m) (((d+e x))^(q+1)) (a+b Log[c (x^n)]))/(e (q+1)))-(f/(e (q+1)))∫(((f x))^(m-1)) (((d+e x))^(q+1)) (a m+b n+b m Log[c (x^n)])dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  (f*x)^m*(d+e*x)^(q+1)*(a+b*Log[c*x^n])/(e*(q+1)) - 
  f/(e*(q+1))*Int[(f*x)^(m-1)*(d+e*x)^(q+1)*(a*m+b*n+b*m*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && ILtQ[q,-1] && GtQ[m,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  when  q+1∈(SuperMinus[ℤ])∧ m∈(SuperMinus[ℤ])

Rule: If  q+1∈(SuperMinus[ℤ])∧ m∈(SuperMinus[ℤ]), then

∫(((f x))^m) (((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  ⟶  
-(((((f x))^(m+1)) (((d+e (x^2)))^(q+1)) (a+b Log[c (x^n)]))/(2 d f (q+1)))+(1/(2 d (q+1)))∫(((f x))^m) (((d+e (x^2)))^(q+1)) (a (m+2 q+3)+b n+b (m+2 q+3) Log[c (x^n)])dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  -(f*x)^(m+1)*(d+e*x^2)^(q+1)*(a+b*Log[c*x^n])/(2*d*f*(q+1)) + 
  1/(2*d*(q+1))*Int[(f*x)^m*(d+e*x^2)^(q+1)*(a*(m+2*q+3)+b*n+b*(m+2*q+3)*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && ILtQ[q,-1] && ILtQ[m,0]

5:  ∫(x^m) (((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  when  (m/2)∈ℤ ∧ q-(1/2)∈ℤ ∧ ¬(m+2 q<-2 ∨ d>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d+e (x^2)))^q)/(((1+(e/d) (x^2)))^q))==0

Rule: If (m/2)∈ℤ ∧ q-(1/2)∈ℤ ∧ ¬(m+2 q<-2 ∨ d>0), then

∫(x^m) (((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  ⟶  (((d^(IntPart[q]))(((d+e (x^2)))^(FracPart[q])))/(((1+(e/d) (x^2)))^(FracPart[q]))) ∫(x^m) (((1+(e/d) (x^2)))^q) (a+b Log[c (x^n)])dx

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  d^IntPart[q]*(d+e*x^2)^FracPart[q]/(1+e/d*x^2)^FracPart[q]*Int[x^m*(1+e/d*x^2)^q*(a+b*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,n},x] && IntegerQ[m/2] && IntegerQ[q-1/2] && Not[LtQ[m+2*q,-2] || GtQ[d,0]]

Int[x_^m_.*(d1_+e1_.*x_)^q_*(d2_+e2_.*x_)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  (d1+e1*x)^q*(d2+e2*x)^q/(1+e1*e2/(d1*d2)*x^2)^q*Int[x^m*(1+e1*e2/(d1*d2)*x^2)^q*(a+b*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n},x] && EqQ[d2*e1+d1*e2,0] && IntegerQ[m] && IntegerQ[q-1/2]

6.  ∫(((((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])

1.  ∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])

1:  ∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])∧ q>0

Rule: Algebraic expansion

Basis: ((((d+e x))^q)/x)==((d (((d+e x))^(q-1)))/x)+e (((d+e x))^(q-1))

Rule: If  p∈(SuperPlus[ℤ])∧ q>0, then

∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  d ∫(((((d+e x))^(q-1)) (((a+b Log[c (x^n)]))^p))/x)dx+e ∫(((d+e x))^(q-1)) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(d_+e_.*x_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  d*Int[(d+e*x)^(q-1)*(a+b*Log[c*x^n])^p/x,x] + 
  e*Int[(d+e*x)^(q-1)*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,0] && GtQ[q,0] && IntegerQ[2*q]

2:  ∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])∧ q<-1

Rule: Algebraic expansion

Basis: ((((d+e x))^q)/x)==((((d+e x))^(q+1))/(d x))-((e (((d+e x))^q))/d)

Rule: If  p∈(SuperPlus[ℤ])∧ q<-1, then

∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  (1/d)∫(((((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^p))/x)dx-(e/d)∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(d_+e_.*x_)^q_*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  1/d*Int[(d+e*x)^(q+1)*(a+b*Log[c*x^n])^p/x,x] - 
  e/d*Int[(d+e*x)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,0] && LtQ[q,-1] && IntegerQ[2*q]

2:  ∫(((((d+e (x^r)))^q) (a+b Log[c (x^n)]))/x) dx  when  q-(1/2)∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Rule: If  q-(1/2)∈ℤ, let u->∫((((d+e (x^r)))^q)/x) dx, then

∫(((((d+e (x^r)))^q) (a+b Log[c (x^n)]))/x)dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.])/x_,x_Symbol] :=
  With[{u=IntHide[(d+e*x^r)^q/x,x]},  
  u*(a+b*Log[c*x^n]) - b*n*Int[Dist[1/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,n,r},x] && IntegerQ[q-1/2]

3:  ∫(((((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])∧ q+1∈(SuperMinus[ℤ])

Rule: Algebraic expansion

Basis: ((((d+e (x^r)))^q)/x)==((((d+e (x^r)))^(q+1))/(d x))-((e (x^(r-1)) (((d+e (x^r)))^q))/d)

Rule: If  p∈(SuperPlus[ℤ])∧ q+1∈(SuperMinus[ℤ]), then

∫(((((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  (1/d)∫(((((d+e (x^r)))^(q+1)) (((a+b Log[c (x^n)]))^p))/x)dx-(e/d)∫(x^(r-1)) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(d_+e_.*x_^r_.)^q_*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  1/d*Int[(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])^p/x,x] - 
  e/d*Int[x^(r-1)*(d+e*x^r)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[p,0] && ILtQ[q,-1]

7:  ∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  m∈ℤ ∧ 2 q∈ℤ ∧ r∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Note: If  m∈ℤ ∧ q-(1/2)∈ℤ, then the terms of ∫(x^m) (((d+e x))^q)dx will be algebraic functions or constants times an inverse function.

Rule: If  m∈ℤ ∧ 2 q∈ℤ ∧ r∈ℤ, let u->∫(((f x))^m) (((d+e (x^r)))^q)dx, then

∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^r)^q,x]},
  Dist[(a+b*Log[c*x^n]),u,x] - b*n*Int[SimplifyIntegrand[u/x,x],x] /;
 (EqQ[r,1] || EqQ[r,2]) && IntegerQ[m] && IntegerQ[q-1/2] || InverseFunctionFreeQ[u,x]] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && IntegerQ[2*q] && (IntegerQ[m] && IntegerQ[r] || IGtQ[q,0])

8:  ∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  q∈ℤ ∧ (q>0 ∨ m∈ℤ ∧ r∈ℤ)

Derivation: Algebraic expansion

Rule: If  q∈ℤ ∧ (q>0 ∨ m∈ℤ ∧ r∈ℤ), then

∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  ∫(a+b Log[c (x^n)])ExpandIntegrand[(((f x))^m) (((d+e (x^r)))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*Log[c*x^n]),(f*x)^m*(d+e*x^r)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && IntegerQ[q] && (GtQ[q,0] || IntegerQ[m] && IntegerQ[r])

9:  ∫(x^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  q∈ℤ ∧ (r/n)∈ℤ ∧ ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ p∈(SuperPlus[ℤ]))

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m) F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule: If q∈ℤ ∧ (r/n)∈ℤ ∧ ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ p∈(SuperPlus[ℤ])), then

∫(x^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((d+e (x^(r/n))))^q) (((a+b Log[c x]))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(d+e*x^(r/n))^q*(a+b*Log[c*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,e,m,n,p,q,r},x] && IntegerQ[q] && IntegerQ[r/n] && IntegerQ[Simplify[(m+1)/n]] && (GtQ[(m+1)/n,0] || IGtQ[p,0])

10:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  q∈ℤ ∧ (q>0 ∨ p∈(SuperPlus[ℤ])∧ m∈ℤ ∧ r∈ℤ)

Derivation: Algebraic expansion

Rule: If  q∈ℤ ∧ (q>0 ∨ p∈(SuperPlus[ℤ])∧ m∈ℤ ∧ r∈ℤ), then

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((a+b Log[c (x^n)]))^p)ExpandIntegrand[(((f x))^m) (((d+e (x^r)))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*Log[c*x^n])^p,(f*x)^m*(d+e*x^r)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q,r},x] && IntegerQ[q] && (GtQ[q,0] || IGtQ[p,0] && IntegerQ[m] && IntegerQ[r])

U:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Rule:

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d+e*x^r)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q,r},x]

N:  ∫(((f x))^m) (u^q) (((a+b Log[c (x^n)]))^p)dx  when  u==d+e (x^r)

Derivation: Algebraic normalization

Rule: If  u==d+e (x^r), then

∫(((f x))^m) (u^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(f_.*x_)^m_.*u_^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Int[(f*x)^m*ExpandToSum[u,x]^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,f,m,n,p,q},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Rules for integrands of the form (((f+g x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)

1:  ∫(((f+g x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  when  e f-d g≠0 ∧ m+q+2==0 ∧ p∈(SuperPlus[ℤ])∧ q<-1

Derivation: Integration by parts

Basis: If  m+q+2==0, then (((f+g x))^m) (((d+e x))^q)==(∂_x)(((((f+g x))^(m+1)) (((d+e x))^(q+1)))/((q+1) (e f-d g)))

Basis: (∂_x)(((a+b Log[c (x^n)]))^p)==((b n p (((a+b Log[c (x^n)]))^(p-1)))/x)

Rule: If  e f-d g≠0 ∧ m+q+2==0 ∧ p∈(SuperPlus[ℤ])∧ q<-1, then

∫(((f+g x))^m) (((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  
(((((f+g x))^(m+1))(((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^p))/((q+1) (e f-d g)))-((b n p)/((q+1) (e f-d g))) ∫(((((f+g x))^(m+1)) (((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_)^q_*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  (f+g*x)^(m+1)*(d+e*x)^(q+1)*(a+b*Log[c*x^n])^p/((q+1)*(e*f-d*g)) - 
  b*n*p/((q+1)*(e*f-d*g))*Int[(f+g*x)^(m+1)*(d+e*x)^(q+1)*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,q},x] && NeQ[e*f-d*g,0] && EqQ[m+q+2,0] && IGtQ[p,0] && LtQ[q,-1]